Prev: 34733 Up: Map Next: 34858
34762: Print text at location HL to screen
Input
HL Points to text data to print
34762 LD IX,24005 Point IX at start of temporary text buffer
34766 LD A,255 Prepare recursion depth counter for loop...
34768 LD (23488),A ...
This entry point is used by the routine at 34887.
34771 LD A,(23488) Increase recursion depth counter...
34774 INC A ...
34775 LD (23488),A ...
34778 PUSH HL Store HL
34779 CALL 54215 Update attribute virtual text cursor based upon current bitmap virtual text cursor
34782 POP HL Restore HL
34783 DEC HL Prepare pointer to text to print for loop
This entry point is used by the routines at 34858, 34934 and 36602.
34784 LD A,(23488) Load A with value in recursion depth counter...
34787 CP 255 ...and if this is 255 (i.e. no more text to print)...
34789 RET Z ...then return
34790 INC HL Advance to next character code to be printed...
34791 LD A,(HL) ...and load into A
34792 OR A If character code is zero (i.e. end marker)...
34793 JP Z,34861 ...then return from current level of text printing
34796 CP 32 If character code is 32 (SPACE)...
34798 JP Z,36602 ...then print word in temporary text buffer to screen, wrapping text if necessary, then jump to 34784 to load next word
34801 CP 31 If character code is 31...
34803 JP Z,34968 ...then print the Current Character's name
34806 CP 29 If character code is 29...
34808 JP Z,34958 ...then print the Current Object's name
34811 CP 28 If character code is 28...
34813 JP Z,34948 ...then print the Current Starship Location's name
34816 CP 19 If character code is 19...
34818 JP Z,34918 ...then toggle BRIGHT flag then loop back to 34784 for next data
34821 CP 18 If character code is 18...
34823 JP Z,34922 ...then toggle FLASH flag then loop back to 34784 for next data
34826 CP 17 If character code is 17...
34828 JP Z,34930 ...then change PAPER colour based upon following data byte then loop back to 34784 for next data
34831 CP 16 If character code is 16...
34833 JP Z,34934 ...then change INK colour based upon following data byte then loop back to 34784 for next data
34836 CP 14 If character code is 14 (carriage return / line feed to start of next character row down within window)...
34838 JP Z,36602 ...then print word in temporary text buffer to screen, wrapping text if necessary, then jump to 34784 to load next word
34841 CP 13 If character code is 13 (carriage return / line feed to start of next character row down)...
34843 JP Z,36602 ...then print word in temporary text buffer to screen, wrapping text if necessary, then jump to 34784 to load next word
34846 CP 91 If character code is 91 or greater (i.e. special character)...
34848 JP NC,34887 ...then print an entry from the common words table
34851 LD (IX+0),A Load character into temporary text buffer
34854 INC IX Advance to next position in temporary text buffer
34856 JR 34784 Loop back to 34784
Prev: 34733 Up: Map Next: 34858