Routines
Prev: 26976 Up: Map Next: 27136
26997: Initialise data and start a new game
Used by the routine at 26670.
Input
IY 23610
26997 LD A,28 Set Current Starship Location in " LOCATION : [name of Current Starship Location]" text at 38298 to the name of the Current Starship Location (28)
26999 LD (38307),A
27002 CALL 35690 Play upward scale sound
27005 LD A,70 Store 70 (yellow INK, black PAPER, BRIGHT) at 23695
27007 LD (23695),A
27010 LD HL,37329 Copy data from 37329 - 37472 (USS Pisces' initial stats, characters' initial stats, table of object properties for first four objects) to 25012 - 25155 (USS Pisces' current stats, characters' current stats, unused data block)
27013 LD DE,25012
27016 LD BC,144
27019 LDIR
27021 LD HL,36797 Copy data from 36797 - 36804 (Magic Knight's initial data) to 25156 - 25163 (Magic Knight's current data)
27024 LD BC,8
27027 LDIR
27029 LD HL,36805 Copy data from 36805 - 36884 (characters' initial inventories and part of characters' initial positions) to 25164 - 25243 (characters' current inventories and unused data block) (see trivia)
27032 LD BC,80
27035 LDIR
27037 LD HL,36875 Copy data from 36875 - 36916 (characters' initial positions and first two entries in objects' initial positions) to 25244 - 25285 (characters' current positions and unused data block)...(see trivia)
27040 LD BC,42
27043 LDIR
27045 LD HL,36911 Copy data from 36911 - 37021 (objects' initial positions) to 25286 - 25396 (objects' current positions)
27048 LD BC,111
27051 LDIR
27053 LD HL,53361 Copy data from 53361 - 53410 (initial planetary data) to 25397 - 25446 (current planetary data)
27056 LD BC,50
27059 LDIR
27061 LD H,D Load HL with value in DE (25447)
27062 LD L,E
27063 INC DE Advance DE by one byte
27064 LD BC,15 Load memory locations at 25447 - 25462 with zeroes
27067 LD (HL),0
27069 LDIR
27071 CALL 34265 Set Magic Knight's available action flags and validate I.D. Card if appropriate
27074 XOR A Load A and HL with zero
27075 LD H,A
27076 LD L,A
27077 LD (23675),HL Interrupt routine flags
27080 LD (23672),A Set frame counter to zero
27083 LD (23673),HL
27086 INC A Set unknown / unused flag 2 to 1
27087 LD (23480),A
27090 LD A,30 Set number of days left to 30
27092 LD (23457),A
27095 LD A,13 Set USS Pisces' current location to Brightstar (13)
27097 LD (23700),A
27100 ADD A,A Load BC with 26 (A × 2)
27101 LD C,A
27102 LD B,0
27104 LD HL,25398 Point HL at first attribute entry in table of current planetary data and add BC as offset to point to data for Brightstar
27107 ADD HL,BC
27108 LD A,(HL) Load A with attribute of Brightstar planet and set colour of planet on viewscreen accordingly
27109 LD (52196),A
27112 LD HL,1286 Set right exit from USS Pisces, 5 (The Airlock) to USS Pisces, 6 (The Life Boat) and left exit from USS Pisces, 6 (The Life Boat) to USS Pisces, 5 (The Airlock)
27115 LD (37033),HL
27118 LD HL,50850 Set room layout data pointer address for Retreat, 2 to address of "with barrier" version of room 09 (50956)
27121 LD (50161),HL
27124 LD A,2 Move Magic Knight into USS Pisces, 2 (The Transporter Room), draw room and initialise room-specific data
27126 CALL 27762
27129 SET 0,(IY+65) Set game-in-progress flag
27133 JP 27139 Jump into main game loop (process keyboard input and move Magic Knight or enter menus)
Prev: 26976 Up: Map Next: 27136